MPL Model Library MPL Model Library



Breck and Dapper,  Example 1.1,  Shapiro

   {  Exmpl1-1_BreckAndDapper.mpl  }

   {  Roy D. Shapiro, Optimization Models for Planning and Allocation  }

   {  Chapter 1,  Example 1,  Product-Mix,  Size: 5x6,  Page 12  }


TITLE
    BreckAndDapper;

INDEX
    drill  :=  1..4;

DATA
    PlastReq[drill]  := (0.82, 0.62, 1.42, 2.03);      !lb
    CopperReq[drill] := (0.43, 0.69, 0.33, 0.20);      !lb
    WireReq[drill]   := (15, 16, 9, 9);                !yd

    Contrib[drill]   := (12.50, 11.30, 17.20, 19.90);  !dollars

    PlastAvail       :=  16000;      !lb
    CopperAvail      :=   5000;      !lb
    WireOnHand       :=   8000;      !yd

    ProdWireCap      :=  80000;      !yd
    ProdWireRate     :=  3.6/100;    !lb/yd

    WireProdCost     :=  0.14;
    WirePurchaseCost :=  0.29;

VARIABLES
    Produce[drill] -> x;
    WirePurchase   -> Wp;
    WireProduce    -> Wm;


MODEL

    MAX TotalProfit  =  SUM(drill: Contrib * Produce) 
                      - WireProdCost * WireProduce
                      - WirePurchaseCost * WirePurchase;

SUBJECT TO
    PlastLimit:
        SUM(drill: PlastReq * Produce)  <=  PlastAvail;

    CopperLimit:
        SUM(drill: CopperReq * Produce)
      + ProdWireRate * WireProduce  <=  CopperAvail;

    WireLimit:
        SUM(drill: WireReq * Produce)  <=  WireOnHand + WireProduce + WirePurchase;

    WireProdLimit:
        WireProduce  <=  ProdWireCap; 

    Marketing:
        Produce[1] + Produce[2]  >=  Produce[3] + Produce[4];

END




Return to MPL Model Library