MPL Model Library MPL Model Library



Product-Mix,  Example 1.2-1,  H.P. Williams

    {  Exmpl1.2-1_ProdMix.mpl  }

    {  H.P. Williams, Model Building in Mathematical Programming, 3rd ed.  }

    {  Chapter 1.2,  Example 1,  Product-Mix,  Size: 3x5,  Page 5  }


TITLE
    EngineeringFactory;

INDEX
    product = 1..5;
    process = (Grinding, Drilling);

DATA
    Profit[product] := (550, 600, 350, 400, 200);
    ProcessHours[process,product] := (12, 20,  0, 25, 15,
                                      10,  8, 16,  0,  0);
    AssemblyTime        := 20;
    DaysPerWeek         :=  6;
    HoursPerShift       :=  8;
    HoursPerDay         :=  2*HoursPerShift;
    Workers             :=  8;
    Machines[process]   :=  (3, 2);
    WorkHoursAvail      :=  Workers * DaysPerWeek * HoursPerShift;
    MachHoursAvail[process] := Machines * DaysPerWeek * HoursPerDay;

VARIABLES
    Produce[product] -> Prod;

MODEL

    MAX TotalProfit = SUM(product: Profit * Produce);

SUBJECT TO

    ProcessLimit[process] -> Proc:

       SUM(product: ProcessHours * Produce) <= MachHoursAvail;

    WorkLimit:

       SUM(product: AssemblyTime * Produce) <= WorkHoursAvail;

END




Return to MPL Model Library