MPL Model Library MPL Model Library



Goal Programming, Example 7.5-1, Hillier and Lieberman

   {  Exmpl7.5-1_DewrightCo.mpl  }

   {  Hillier and Lieberman, Introduction to Operations Research, 7th ed.  }

   {  Chapter 7.5,  Example 1,  Dewright Co.,  Size: 3x7,  Page 333  }

TITLE
   Dewright_Co;

INDEX
   product := 1..3;
   factor  := (Profit, Employment, Investment);
   deviation := ("Over", "Under");

DATA
   Goal[factor] :=  (125, 40, 55);

   PenaltyWeight[deviation, factor] := (0, 2, 3,
                                        5, 4, 0);

   UnitContrib[factor, product] := 

      (12,  9, 15, 
        5,  3,  4, 
        5,  7,  8);
    
    

DECISION VARIABLES
   ProdRate[product];
   Amount[factor, deviation] WHERE (PenaltyWeight > 0);

MODEL
   
   MIN WeightedSum = SUM(deviation, factor: PenaltyWeight * Amount);

SUBJECT TO

   Calc[factor] :

        SUM(product: ProdRate * UnitContrib) 
     = 
        Goal + Amount[deviation:="Over"] - Amount[deviation:="Under"];

END



Return to MPL Model Library