MPL Model Library MPL Model Library



Semicond Eletronics,  Example 3.7-9,  Winston

   {  Exmpl3.7-9_Semicond.mpl  }

   {  Winston, Operations Research, Applications and Algorithms, 3rd ed.  }

   {  Chapter 3.7,  Example 9,  Financial Planning,  Size: 4x2,  Page 82  }


TITLE
    SemicondElectronics;

INDEX
    product := (TapeRec, Radio);
   
DATA
    SellingPrice[product]  := (100, 90);
    LaborCost[product]     := (50, 35);
    RawMatCost[product]    := (30, 40);

    ContribProfit[product] := SellingPrice - LaborCost - RawMatCost;

    RawMatAvail[product]   := (100, 100);

    CashOnHandDec1      := 10000;   
    AccountsRecDec1     :=  3000;
    InventoryValueDec1  :=  7000;
    LiabilitiesDec1     := 10000;

    RawMatReceivedJan1  :=  2000;

    AccRecCollectDec    :=  2000;
    LoanPaymentDec      :=  1000;
    MonthlyRentDec      :=  1000;

    MinCashOnHandJan    :=  4000;
    MinAssetLiabRatio   :=  2;
      
VARIABLES
    ProduceDec[product] -> Prod;

MACROS
    CashPositionJan1   :=  CashOnHandDec1 + AccRecCollectDec
                         - LoanPaymentDec - MonthlyRentDec
                         - SUM(product: LaborCost * ProduceDec);

    AccountsRecJan1    :=  AccountsRecDec1 
                         + SUM(product: SellingPrice * ProduceDec)
                         - AccRecCollectDec;

    InventoryValueJan1 :=  InventoryValueDec1
                         - SUM(product: RawMatCost * ProduceDec)
                         + RawMatReceivedJan1;

    LiabilitiesJan1    :=  LiabilitiesDec1
                         - LoanPaymentDec
                         + RawMatReceivedJan1;

    AssetsJan1         :=  CashPositionJan1 + AccountsRecJan1 + InventoryValueJan1;

MODEL

    MAX TotalProfit = SUM(product: ContribProfit * ProduceDec);

SUBJECT TO
    RawMatLimit[product]:
        ProduceDec  <=  RawMatAvail;
 
    CashBalance:
        CashPositionJan1  >=  MinCashOnHandJan;

    AssetLiabRatio:
       AssetsJan1 >= MinAssetLiabRatio * LiabilitiesJan1;

END




Return to MPL Model Library