MPL Model Library MPL Model Library



Production Planning,  Example 5.3-2,  H.P.Williams

    {  Exmpl5.3-2_ProdPlan.mpl  }

    {  H.P. Williams, Model Building in Mathematical Programming, 3rd ed.  }

    {  Chapter 5.3,  Example 2,  Production Planning,  Size: 12x12,  Page 76  }


TITLE
    ProductionPlanning;

INDEX
    shift     := (Regular, Overtime);
    month     := (January, February, March, April);
    month2    := month;

DATA
    ProdCapacity[shift, month] := (100, 150, 140, 160,
                                    50,  75,  70,  80);

    ProdCost[shift] := (1.00, 1.50);

    Demand[month]   := (80, 200, 300, 200);

    StorageCost     := 0.30;

    CombinedCost[month, shift, month2] := 

        ProdCost WHERE (month2 >= month) 
      + StorageCost * (month2 WHERE (month2 > month)
                     - month  WHERE (month2 > month));

VARIABLES
    Produce[month, shift];
    Inventory[month];

MACROS
    TotalProdCost  := SUM(shift, month: ProdCost * Produce);
    TotalStoreCost := SUM(month: StorageCost * Inventory); 

MODEL

    MIN TotalCost = TotalProdCost + TotalStoreCost;

SUBJECT TO

    MaxCapacity[shift, month]:

        Produce <= ProdCapacity;

    InventoryBalance[month]:

        Inventory  =  Inventory[month-1] + SUM(shift: Produce) - Demand;

END



Return to MPL Model Library